Using the macros

## 13.2 Using the macros

- Source annotation aware macro transformations

The following declarations and built-ins control macro expansion:

> local macro(+TermClass, +TransPred, +Options)
>   defines a macro for the given TermClass. The transformation itself will be performed by the predicate TransPred.
> export macro(+TermClass, +TransPred, +Options)
>   as above, except that the macro is available to other modules.
> erase_macro(+TermClass, +Options)
>   erases the macro that is currently defined for TermClass. Note that this can only be done in the module where the definition was made.
> current_macro(?TermClass, ?TransPred, ?Options, ?Module)
>   can be used to get information about currently defined visible macros.

Macros are selectively applied only to terms of the specified class. TermClass can take two forms:

> Name/Arity
>   transform all terms with the specified functor
> type(Type)
>   transform all terms of the specified type, where Type is one of the following: compound, string, integer, rational, float, breal, atom, goal.1

The +TransPred argument specifies the predicate that will perform the transformation. It has to be either of arity 2 or 3 and should have the form:

> trans_function(OldTerm, NewTerm [, Module]) :- ... .

or it can be source annotation aware, and be of arity 4 or 5, as follows:

> trans_function(OldTerm, NewTerm, OldAnn, NewAnn [, Module]) :- ... .

At transformation time, the system will call TransPred in the module where macro/3 was invoked. The term to transform is passed as the first argument, the second is a free variable which the transformation predicate should bind to the transformed term. In the case of the source annotation aware version of TransPred, if the term was read in by read_annotated/2,3, the annotated version of the term to transformed is passed in the third argument, and the transformation should bind the fourth argument to the annotated transformed term; otherwise, if no source annotation information is available, the third argument is passed in as a free variable, and the transformation should not bind the fourth argument. In both TransPred cases, the optional last argument is the module where the term was being read in. See section 13.2.1 for more details on annotated terms.

Options is a list which may be empty (in this case the macro defaults to a local read term macro) or contain specifications from the following categories:

- mode:

  > read:
  >   This is a read macro and shall be applied after reading a term (default).
  > write:
  >   This is a write macro and shall be applied before printing a term.

- type:

  > term:
  >   Transform all terms (default).
  > clause:
  >   Transform only if the term is a program clause, i.e., inside compile/1, etc.2 Write macros are applied using the C option in the printf/2 predicate.
  > goal:
  >   Goal-read-macros are transformed only if the term is a subgoal in the body of a program clause. Goal-write macros are applied using the G option in the printf/2 predicate.

- additional specification:

  > protect_arg:
  >   Disable transformation of subterms (optional).
  > top_only:
  >   Consider only the whole term, not subterms (optional).

The following shorthands exist:

> local/export portray(+TermClass, +TransPred, +Options):
>   portray/3 is like macro/3, but the write-option is implied.
> inline(+PredSpec, +TransPred):
>   inline/2 is the same as a goal-read-macro. The visibility is inherited from the transformed predicate.

Here is an example of a conditional read macro:

>     [eclipse 1]: [user].
>      trans_a(a(X,Y), b(Y)) :-    % transform a/2 into b/1,
>             number(X),           % but only under these
>             X > 0.               % conditions

>     :- local macro(a/2, trans_a/2, []).
>       user       compiled traceable 204 bytes in 0.00 seconds

>     yes.
>     [eclipse 2]: read(X).
>             a(1, hello).

>     X = b(hello)                 % transformed
>     yes.
>     [eclipse 3]: read(X).
>             a(-1, bye).

>     X = a(-1, bye)               % not transformed
>     yes.

If the transformation function fails, the term is not transformed. Thus, a(1, zzz) is transformed into b(zzz) but a(-1, zzz) is not transformed. The arguments are transformed bottom-up. It is possible to protect the subterms of a transformed term by specifying the flag protect_arg.

A term can be protected against transformation by quoting it with the “protecting functor” (by default it is no_macro_expansion/1):

>     [eclipse 4]: read(X).
>             a(1, no_macro_expansion(a(1, zzz))).
>     X = b(a(1, zzz)).

Note that the protecting functor is itself defined as a macro:

>     trprotect(no_macro_expansion(X), X).
>     :- export macro(no_macro_expansion/1, trprotect/2, [protect_arg]).

A local macro is only visible in the module where it has been defined. When it is defined as exported, then it is copied to all other modules that contain a use_module/1 or import/1 for this module. The transformation function should also be exported in this case. There are a few global macros predefined by the system, e.g., for -->/2 (grammar rules, see below) or with/2 and of/2 (structure syntax, see section 5.1). These predefined macros can be hidden by local macro definitions.

The global flag macro_expansion can be used to disable macro expansion globally, e.g., for debugging purposes. Use set_flag(macro_expansion, off) to do so.

The next example shows the use of a type macro. Suppose we want to represent integers as s/1 terms:

>     [eclipse 1]: [user].
>      tr_int(0, 0).
>      tr_int(N, s(S)) :- N > 0, N1 is N-1, tr_int(N1, S).
>      :- local macro(type(integer), tr_int/2, []).

>     yes.
>     [eclipse 2]: read(X).
>             3.

>     X = s(s(s(0)))
>     yes.

When we want to convert the s/1 terms back to normal integers so that they are printed in the familiar form, we can use a write macro. Note that we first erase the read macro for integers, otherwise we would get unexpected effects since all integers occurring in the definition of tr_s/2 would turn into s/1 structures:

>     [eclipse 3]: erase_macro(type(integer)).

>     yes.
>     [eclipse 4]: [user].
>      tr_s(0, 0).
>      tr_s(s(S), N) :- tr_s(S, N1), N is N1+1.
>      :- local macro(s/1, tr_s/2, [write]).

>     yes.
>     [eclipse 2]: write(s(s(s(0)))).
>     3
>     yes.

### 13.2.1 Source annotation aware macro transformations

When the macro transformation predicate has 4 or 5 arguments, it is termed source annotation aware, and the extra arguments are used to specify how source information from the original term should be mapped to the transformed term.

An annotated term provides the source information about a term. It is structurally similar to the original term and contains all information about the term, plus additional type information, variable names, and source position annotations for all subterms.

The structure of the descriptive terms is as follows:

>     :- export struct(annotated_term(
>                                     term,     % var, atomic or compound
>                                     type,     % term type (see below)
>                                     file,     % source file name (atom)
>                                     line,     % source line (integer)
>                                     from, to  % source position (integers)
>                      ...
>                     )).

The type-field describes the type of the original term and provide type information similar to those used in type_of/2, except that they convey additional information about variables and end_of_file.

In the case of atomic terms and variables, the term-field simply contains the plain original term. For compound terms, the term-field contains a structure whose functor is the functor of the plain term, but whose arguments are annotated versions of the plain term arguments.

For example, the annotated term representing the source term foo(bar, X, _, 3) is:

>     annotated_term(foo(
>                        annotated_term(bar, atom, ...),
>                        annotated_term(X, var('X'), ...),
>                        annotated_term(_, anonymous, ...),
>                        annotated_term(3, integer, ...)
>                       ),
>                    compound,
>                    ...
>                   )

The file/line/from/to-fields of an annotated term describe the "source position" of the term, as follows:

file
  The canonical file name of the source file (an atom), or the empty atom ’’ if the source is not a file or is not known.
line
  The line number in the source stream (positive integer).
from, to
  The exact term position as integer offsets in the source stream, starting at from and ending at to−1.

The extra arguments for the transformation predicate are a pair of annotated terms for the original and transformed term. The predicate will be supplied with the annotated term for the original term if available, and the predicate is responsible for specifying the annotated term for the transformed term—the structure of the transformed annotated term must match the annotated term structure expected for the transformed term. If no annotated information is available, the original annotated term will be a variable, and the predicate must not bind the transformed annotated term.

For an example, here is a source annotation aware version of the previous trans_a/2 example:

    [eclipse 1]: [user].
    ...

     trans_a(a(X,Y), b(Y), AnnA, AnnTrans) :-
            number(X),
            X > 0,
            ( var(AnnA) ->
                  true      % no source information, leave AnnTrans as var
            ;
                  AnnA = annotated_term{term:a(_AnnX, AnnY),
                                        file:File, line:Line,
                                        from:From,to:To},
                  AnnTrans = annotated_term{term:b(AnnY),
                                        type: compound,
                                        file:File, line:Line,
                                        from:From,to:To}
             ).

    :- local macro(a/2, trans_a/4, []).

    Yes (0.23s cpu)
    [eclipse 2]: read_annotated(user, X, Y).
     a(3,bar(X)).

    X = b(bar(X))
    Y = annotated_term(b(annotated_term(bar(annotated_term(X, var('X'), user, 18,
    654, 655)), compound, user, 18, 650, 654)), compound, user, 18, 646, 648)

In the example, the main functor of the transformed predicate, b/1, inherits the annotation information for the original term’s principal functor, a/2. The argument Y in the transformed term takes the annotation information from the corresponding argument in the original term.

The source annotation aware transformation predicate facility is provided to allow the user to access the details of how the subterms of the original term are mapped to the transformed term. Without this extra information, the whole of the transformed term is given the source information (source position, source file etc.) of the original source term. This extra information is useful when the subterms are goals, because without the extra information, source tracing of these goals during debugging will not be done.

1
  type(goal) stands for suspensions.
2
  Note that clause transformation is not performed with assert/1, retract/1 and clause/1. This is a change from previous versions of ECLiPSe.